yggm/libs/sha512.cuh

#ifndef __SHA512_CUH
#define __SHA512_CUH
#include <stdint.h>
#include <stddef.h>
#include <string.h>
#define SHA512_BLOCK_SIZE 128
struct sha512_state {
    uint64_t h[8];
};
#if !defined(COMPACT_DISABLE_ED25519) || !defined(COMPACT_DISABLE_X25519_DERIVE)
__device__ __constant__ sha512_state sha512_initial_state = { {
    0x6a09e667f3bcc908ULL, 0xbb67ae8584caa73bULL,
    0x3c6ef372fe94f82bULL, 0xa54ff53a5f1d36f1ULL,
    0x510e527fade682d1ULL, 0x9b05688c2b3e6c1fULL,
    0x1f83d9abfb41bd6bULL, 0x5be0cd19137e2179ULL,
} };
#endif
__device__ __constant__ uint64_t round_k[80] = {
    0x428a2f98d728ae22ULL, 0x7137449123ef65cdULL,
    0xb5c0fbcfec4d3b2fULL, 0xe9b5dba58189dbbcULL,
    0x3956c25bf348b538ULL, 0x59f111f1b605d019ULL,
    0x923f82a4af194f9bULL, 0xab1c5ed5da6d8118ULL,
    0xd807aa98a3030242ULL, 0x12835b0145706fbeULL,
    0x243185be4ee4b28cULL, 0x550c7dc3d5ffb4e2ULL,
    0x72be5d74f27b896fULL, 0x80deb1fe3b1696b1ULL,
    0x9bdc06a725c71235ULL, 0xc19bf174cf692694ULL,
    0xe49b69c19ef14ad2ULL, 0xefbe4786384f25e3ULL,
    0x0fc19dc68b8cd5b5ULL, 0x240ca1cc77ac9c65ULL,
    0x2de92c6f592b0275ULL, 0x4a7484aa6ea6e483ULL,
    0x5cb0a9dcbd41fbd4ULL, 0x76f988da831153b5ULL,
    0x983e5152ee66dfabULL, 0xa831c66d2db43210ULL,
    0xb00327c898fb213fULL, 0xbf597fc7beef0ee4ULL,
    0xc6e00bf33da88fc2ULL, 0xd5a79147930aa725ULL,
    0x06ca6351e003826fULL, 0x142929670a0e6e70ULL,
    0x27b70a8546d22ffcULL, 0x2e1b21385c26c926ULL,
    0x4d2c6dfc5ac42aedULL, 0x53380d139d95b3dfULL,
    0x650a73548baf63deULL, 0x766a0abb3c77b2a8ULL,
    0x81c2c92e47edaee6ULL, 0x92722c851482353bULL,
    0xa2bfe8a14cf10364ULL, 0xa81a664bbc423001ULL,
    0xc24b8b70d0f89791ULL, 0xc76c51a30654be30ULL,
    0xd192e819d6ef5218ULL, 0xd69906245565a910ULL,
    0xf40e35855771202aULL, 0x106aa07032bbd1b8ULL,
    0x19a4c116b8d2d0c8ULL, 0x1e376c085141ab53ULL,
    0x2748774cdf8eeb99ULL, 0x34b0bcb5e19b48a8ULL,
    0x391c0cb3c5c95a63ULL, 0x4ed8aa4ae3418acbULL,
    0x5b9cca4f7763e373ULL, 0x682e6ff3d6b2b8a3ULL,
    0x748f82ee5defb2fcULL, 0x78a5636f43172f60ULL,
    0x84c87814a1f0ab72ULL, 0x8cc702081a6439ecULL,
    0x90befffa23631e28ULL, 0xa4506cebde82bde9ULL,
    0xbef9a3f7b2c67915ULL, 0xc67178f2e372532bULL,
    0xca273eceea26619cULL, 0xd186b8c721c0c207ULL,
    0xeada7dd6cde0eb1eULL, 0xf57d4f7fee6ed178ULL,
    0x06f067aa72176fbaULL, 0x0a637dc5a2c898a6ULL,
    0x113f9804bef90daeULL, 0x1b710b35131c471bULL,
    0x28db77f523047d84ULL, 0x32caab7b40c72493ULL,
    0x3c9ebe0a15c9bebcULL, 0x431d67c49c100d4cULL,
    0x4cc5d4becb3e42b6ULL, 0x597f299cfc657e2aULL,
    0x5fcb6fab3ad6faecULL, 0x6c44198c4a475817ULL,
};
__device__ __forceinline__ uint64_t load64(const uint8_t* x) {
    return ((uint64_t)x[0] << 56) | ((uint64_t)x[1] << 48) |
        ((uint64_t)x[2] << 40) | ((uint64_t)x[3] << 32) |
        ((uint64_t)x[4] << 24) | ((uint64_t)x[5] << 16) |
        ((uint64_t)x[6] << 8) | ((uint64_t)x[7]);
}
__device__ __forceinline__ void store64(uint8_t* x, uint64_t v) {
    x[0] = (uint8_t)(v >> 56);
    x[1] = (uint8_t)(v >> 48);
    x[2] = (uint8_t)(v >> 40);
    x[3] = (uint8_t)(v >> 32);
    x[4] = (uint8_t)(v >> 24);
    x[5] = (uint8_t)(v >> 16);
    x[6] = (uint8_t)(v >> 8);
    x[7] = (uint8_t)(v);
}
__device__ __forceinline__ uint64_t rot64(uint64_t x, int bits) {
    return (x >> bits) | (x << (64 - bits));
}
__device__ void sha512_block(sha512_state* s, const uint8_t* blk) {
    uint64_t w[16];
#pragma unroll
    for (int i = 0; i < 16; i++) {
        w[i] = load64(blk + i * 8);
    }
    uint64_t a = s->h[0];
    uint64_t b = s->h[1];
    uint64_t c = s->h[2];
    uint64_t d = s->h[3];
    uint64_t e = s->h[4];
    uint64_t f = s->h[5];
    uint64_t g = s->h[6];
    uint64_t h = s->h[7];
#pragma unroll
    for (int i = 0; i < 80; i++) {
        const int idx = i & 15;
        const int idx1 = (i + 1) & 15;
        const int idx7 = (i + 9) & 15;
        const int idx14 = (i + 14) & 15;
        uint64_t s0 = rot64(w[idx1], 1) ^ rot64(w[idx1], 8) ^ (w[idx1] >> 7);
        uint64_t s1 = rot64(w[idx14], 19) ^ rot64(w[idx14], 61) ^ (w[idx14] >> 6);
        uint64_t S0 = rot64(a, 28) ^ rot64(a, 34) ^ rot64(a, 39);
        uint64_t S1 = rot64(e, 14) ^ rot64(e, 18) ^ rot64(e, 41);
        uint64_t ch = (e & f) ^ ((~e) & g);
        uint64_t temp1 = h + S1 + ch + round_k[i] + w[idx];
        uint64_t maj = (a & b) ^ (a & c) ^ (b & c);
        uint64_t temp2 = S0 + maj;
        h = g;
        g = f;
        f = e;
        e = d + temp1;
        d = c;
        c = b;
        b = a;
        a = temp1 + temp2;

        w[idx] += s0 + w[idx7] + s1;
    }
    s->h[0] += a;
    s->h[1] += b;
    s->h[2] += c;
    s->h[3] += d;
    s->h[4] += e;
    s->h[5] += f;
    s->h[6] += g;
    s->h[7] += h;
}
__device__ void sha512_final(sha512_state* s, const uint8_t* blk, size_t total_size) {
    uint8_t temp[SHA512_BLOCK_SIZE];
    memset(temp, 0, sizeof(temp));

    size_t last_size = total_size & (SHA512_BLOCK_SIZE - 1);
    if (last_size) {
        memcpy(temp, blk, last_size);
    }
    temp[last_size] = 0x80;
    if (last_size > (SHA512_BLOCK_SIZE - 9)) {
        sha512_block(s, temp);
        memset(temp, 0, sizeof(temp));
    }
    store64(temp + SHA512_BLOCK_SIZE - 8, total_size << 3);
    sha512_block(s, temp);
}
__device__ void sha512_get(const sha512_state* s, uint8_t* hash, unsigned int offset, unsigned int len) {
    if (offset > SHA512_BLOCK_SIZE)
        return;
    if (len > SHA512_BLOCK_SIZE - offset)
        len = SHA512_BLOCK_SIZE - offset;
    unsigned int i = offset >> 3;
    unsigned int off = offset & 7;
    if (off) {
        uint8_t tmp[8];
        store64(tmp, s->h[i]);
        unsigned int c = 8 - off;
        if (c > len) c = len;
        memcpy(hash, tmp + off, c);
        len -= c;
        hash += c;
        i++;
    }
    while (len >= 8) {
        store64(hash, s->h[i]);
        hash += 8;
        len -= 8;
        i++;
    }
    if (len) {
        uint8_t tmp[8];
        store64(tmp, s->h[i]);
        memcpy(hash, tmp, len);
    }
}
__device__ void sha512_init(struct sha512_state* s) {
    memcpy(s, &sha512_initial_state, sizeof(*s));
}
#endif